[[PAUL FERRIE]]

I am sure i have already answered this question recently but ere goes again since i can't find that post

There are two ways to do this.
1. onEnterFrame

Actionscript:

someButton.onRollOver = function() {
	playMC("for");
};
someButton.onRollOut = function() {
	playMC("back");
};
function playMC(dir) {
	switch (dir) {
		case "for" :
			this.onEnterFrame = function() {
				if (effectMC._currentframe<20) {
					effectMC.gotoAndStop(effectMC._currentframe+1);
				} else {
					delete this.onEnterFrame;
				}
			};
			break;
		case "back" :
			this.onEnterFrame = function() {
				if (effectMC._currentframe>1) {
					effectMC.gotoAndStop(effectMC._currentframe-1);
				} else {
					delete this.onEnterFrame;
				}
			};
			break;

	}
}

2. Using some tween class. In this example i am using Caurina Tweener

Actionscript:

import caurina.transitions.Tweener;
import caurina.transitions.properties.DisplayShortcuts;
DisplayShortcuts.init();
someButton.onRollOver = function() {
	playMC("for");
};
someButton.onRollOut = function() {
	playMC("back");
};
function playMC(dir) {
	switch (dir) {
		case "for" :
			Tweener.addTween(effectMC,{_frame:20, time:1});
			break;
		case "back" :
			Tweener.addTween(effectMC,{_frame:1, time:1});
			break;

	}
}

I have also attached both fla's
Playing frames in reverse using onEnterFrame
Playing frames in reverse using tween class
Hope it helps someone.
Also Blog'ed it

[FlashMove]

Excellent tutorial there Paul

[[PAUL FERRIE]]

Originally Posted by FlashMove

Excellent tutorial there Paul 

Thanks. It feels like i have answered this question a few times in recent weeks

[maxjustlogin]

Useful code.

[SD Surfer]

Thanks for the share. I've been trying to figure out how to get a "Previous" button working in AS3 using something similar to this, but have been unsuccessful.

So, if i had several images all on their own frame and each with their own Tweener transition when navigated to that frame. Is it possible to have a "Previous" button that would not only go back a frame, but play the Tweener animation on that frame in reverse? I'm trying to make a nice AS3 slideshow complete with sleek transitions and next & previous buttons. I've been researching this for days...

"Previous" button code:

Code:

btn_previous.addEventListener(MouseEvent.CLICK, doprevClick);
function doprevClick(e:MouseEvent):void {
prevFrame();
}

[[PAUL FERRIE]]

Can't say without knowing what's going on in these other frames. Can you post your fla?

[Scottae]

Why check if _currentframe is less than frame 20 when going forward? You should check if _currentframe is less than _totalframes to keep things usable across any movieclip. See Play a movie in reverse

[mitree]

I would edvise to take a look at http://www.greensock.com/. great tween class that gives you all the ways to go back and forward...

[xiaotuanzi]

That's good job.